Автор перевода: Майкл "Antares" Клишин	Предыдущая | Следующая | Оглавление

Sound.getPan()

Доступность

Flash Player 5.

Синтаксис

my_sound.getPan() : Number

Параметры

Нет.

Возвращает

Число.

Описание

Метод; соотношение баланса каналов, установленное при последнем вызове метода setPan(), в виде числа от -100 (только левый канал) до 100 (только правый). (0 определяет среднее положение.) Этот метод воздействует и на те звуки, которые будут загружены в звуковой объект в будущем.

Этот метод обычно используется вместе с setVolume() или setTransform().

Пример

В следующем примере при помощи Drawing API создается слайдер. При его перемещении пользователем происходит изменение баланса звука, числовое значение баланса отражается в динамически созданном текстовом поле:

var bar_width:Number = 200;
this.createEmptyMovieClip("bar_mc", this.getNextHighestDepth());
with (bar_mc) {
  lineStyle(4, 0x000000);
  moveTo(0, 0);
  lineTo(bar_width+4, 0);
  lineStyle(0, 0x000000);
  moveTo((bar_width/2)+2, -8);
  lineTo((bar_width/2)+2, 8);
}
bar_mc._x = 100;
bar_mc._y = 100;

this.createEmptyMovieClip("knob_mc", this.getNextHighestDepth());
with (knob_mc) {
  lineStyle(0, 0x000000);
  beginFill(0xCCCCCC);
  moveTo(0, 0);
  lineTo(4, 0);
  lineTo(4, 10);
  lineTo(0, 10);
  lineTo(0, 0);
  endFill();
}
knob_mc._x = bar_mc._x+(bar_width/2);
knob_mc._y = bar_mc._y-(knob_mc._height/2);

knob_mc.left = knob_mc._x-(bar_width/2);
knob_mc.right = knob_mc._x+(bar_width/2);
knob_mc.top = knob_mc._y;
knob_mc.bottom = knob_mc._y;

knob_mc.onPress = function() {
  this.startDrag(false, this.left, this.top, this.right, this.bottom);
};
knob_mc.onRelease = function() {
  this.stopDrag();
  var multiplier:Number = 100/(this.right-this.left)*2;
  var pan:Number = (this._x-this.left-(bar_width/2))*multiplier;
  my_sound.setPan(pan);
  pan_txt.text = my_sound.getPan();
};

var my_sound:Sound = new Sound();
my_sound.loadSound("song2.mp3", true);
this.createTextField("pan_txt", this.getNextHighestDepth(), knob_mc._x, knob_mc._y+knob_mc._height, 20, 22);
pan_txt.selectable = false;
pan_txt.autoSize = "center";
pan_txt.text = my_sound.getPan();

См. также

Sound.setPan()

Смотреть комментарии LiveDocs		Предыдущая | Следующая | Оглавление